flet is a macro defined in cl.el.gz.

This macro is obsolete since 24.3; use either cl-flet or cl-letf.

Signature
(flet ((FUNC ARGLIST BODY...) ...) FORM...)

Documentation
Make temporary overriding function definitions.

This is an analogue of a dynamically scoped let that operates on the function
cell of FUNCs rather than their value cell.
If you want the Common-Lisp style of flet, you should use cl-flet.
The FORMs are evaluated with the specified function definitions in place,
then the definitions are undone (the FUNCs go back to their previous
definitions, or lack thereof).

View in manual

References
flet is unused in cl.el.gz.

Find all references Functions used by flet

Debugging
Enable edebug Enable tracing
Disassemble Forget

Source Code
;; Defined in /usr/share/emacs/29.3/lisp/obsolete/cl.el.gz
;; This should really have some way to shadow 'byte-compile properties, etc.
(defmacro flet (bindings &rest body)
  "Make temporary overriding function definitions.
This is an analogue of a dynamically scoped `let' that operates on the function
cell of FUNCs rather than their value cell.
If you want the Common-Lisp style of `flet', you should use `cl-flet'.
The FORMs are evaluated with the specified function definitions in place,
then the definitions are undone (the FUNCs go back to their previous
definitions, or lack thereof).

\(fn ((FUNC ARGLIST BODY...) ...) FORM...)"
  (declare (indent 1) (debug cl-flet)
           (obsolete "use either `cl-flet' or `cl-letf'."  "24.3"))
  `(letf ,(mapcar
           (lambda (x)
             (if (or (eq (car-safe (symbol-function (car x))) 'macro)
                     (cdr (assq (car x) macroexpand-all-environment)))
                 (error "Use `labels', not `flet', to rebind macro names"))
             (let ((func `(cl-function
                           (lambda ,(cadr x)
                             (cl-block ,(car x) ,@(cddr x))))))
               (when (macroexp-compiling-p)
                 ;; Bug#411.  It would be nice to fix this.
                 (and (get (car x) 'byte-compile)
                      (error "Byte-compiling a redefinition of `%s' \
will not work - use `labels' instead" (symbol-name (car x))))
                 ;; FIXME This affects the rest of the file, when it
                 ;; should be restricted to the flet body.
                 (and (boundp 'byte-compile-function-environment)
                      (push (cons (car x) (eval func t))
                            byte-compile-function-environment)))
               (list `(symbol-function ',(car x)) func)))
           bindings)
     ,@body))

Symbol Properties
byte-obsolete-info
  ("use either `cl-flet' or `cl-letf'." nil "24.3")
edebug-form-spec
  cl-flet
lisp-indent-function
  1